Will my sketch "wait" until Blynk.notify is complete?

In this pseudo-ish code example:

void sendNotification()
{
  Blynk.notify("You've been notified!");
  doThing1();
  doThing2();
}

…should doThing1 and doThing2 execute immediately regardless of what happens with Blynk.notify, or will they wait until notify clears the server (understanding that probably happens very quickly)?

All the code, FYI:

#include <SimpleTimer.h>
#define BLYNK_PRINT Serial
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <OneWire.h>
#include <DallasTemperature.h>
#define ONE_WIRE_BUS 2

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);

DeviceAddress ds18b20lk = { 0x28, 0xEE, 0x27, 0x16, 0x01, 0x16, 0x02, 0xED }; // LK

float tempLK; // Room temp
int tempLKhighAlarm = 200;

char auth[] = "fromBlynkApp";

SimpleTimer timer;

void setup()
{
  Serial.begin(9600);
  Blynk.begin(auth, "ssid", "pw");

  sensors.begin();
  sensors.setResolution(ds18b20lk, 10);

  timer.setInterval(2000L, sendTemps); // Temperature sensor polling interval
}

// Input from Blynk app menu to select room temperature that triggers alarm
BLYNK_WRITE(V21) {
  switch (param.asInt())
  {
    case 1: { // Alarm Off
        tempLKhighAlarm = 200;
        break;
      }
    case 2: { // 80F Alarm
        tempLKhighAlarm = 80;
        break;
      }
    case 3: { // 81F Alarm
        tempLKhighAlarm = 81;
        break;
      }
    case 4: { // 82F Alarm;
        tempLKhighAlarm = 82;
        break;
      }
    case 5: { // 83F Alarm
        tempLKhighAlarm = 83;
        break;
      }
    case 6: { // 84F Alarm
        tempLKhighAlarm = 84;
        break;
      }
    default: {
        Serial.println("Unknown item selected");
      }
  }
}

void notifyAndOff()
{
  Blynk.notify(String("LK's room is ") + tempLK + "°F. Alarm disabled until reset."); // Send notification.
  Blynk.virtualWrite(V21, 1); // Rather than fancy timing, just disable alarm until reset.
  tempLKhighAlarm = 200; // Belt and suspenders since Blynk.virtualWrite isn't disabling the alarm.
}

void sendTemps()
{
  sensors.requestTemperatures(); // Polls the sensors

  tempLK = sensors.getTempF(ds18b20lk);

  if (tempLK > 0)
  {
    Blynk.virtualWrite(6, tempLK);
  }
  else
  {
    Blynk.virtualWrite(6, "ERR");
  }

  if (tempLK >= tempLKhighAlarm)
  {
    notifyAndOff();
  }
}

void loop()
{
  Blynk.run();
  timer.run();
}

It will happen straight away. Notify is not blocking your code.

I’ve got some other things in mind then… thanks!