Some issues after updating blynk libray

Hello, i have a project that runs since march aprox. It is a gate access control that i have done with the help of this community. Thank you COSTAS!
Some days ago i needed to add a new RFID tag, and everything went south…
The working code was based on a previous version of blynk library. Now it does not connect. II know it might be from the server.config as i also updated the server to latest version. the rest of the code still works, meaning RFID tags works as intended. When (once in 100 tries) the esp does connect to my server, the blynk control works, but no RFID whatsoever. Can someone please point me on the right direction?

P.S. In the router, ports 80, 8080 are forwarded to the server 8080 . 9443 is forwarded to 9443. Never touched the router in a long time, it is the same as it was before, when everything worked fine.

Actual message now;

WiFi OK, trying connection to server...
[260525] Connecting to server.ro:80

Here is the entire code (i know it might be messy but worked flawless) and i will attach the server.properties at the end.

#define BLYNK_PRINT Serial
#ifndef BLYNK_HEARTBEAT
#define BLYNK_HEARTBEAT      60
#endif

// Network timeout in milliseconds.
#ifndef BLYNK_TIMEOUT_MS
#define BLYNK_TIMEOUT_MS     2000UL
#endif

// Limit the amount of outgoing commands.
#ifndef BLYNK_MSG_LIMIT
#define BLYNK_MSG_LIMIT      200
#endif
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <SPI.h>
#include "MFRC522.h"
#include <SimpleTimer.h>
#include <TimeLib.h>
#include <WidgetRTC.h>
#include "functions.h"
#define BLYNK_DEFAULT_PORT 8080

SimpleTimer timer;

//WidgetLCD lcd(V4);
WidgetRTC rtc;
WidgetTable table;
BLYNK_ATTACH_WIDGET(table, V6);

const char* ssid          = "ssid";
const char* password      = "my pass";
const char* host          = "server.ro";
const char  auth[]        = "my token";

unsigned long uidDec, uidDecTemp; 
#define RST_PIN  5                // RST-PIN for RC522 - ESP pin D1
#define SS_PIN  4                 // SDA-PIN for RC522 -  ESP pin D2
MFRC522 mfrc522(SS_PIN, RST_PIN); // Create MFRC522 instance


int rowIndex = 0;
int lock = 0;
int button = 0; //ESP D3 (a lock status switch between D3 and GND)
int bell = 2;   //ESP D4 (doorbell switch between D4 and GND)
int relay = 15; //ESP D8
int UP_LED = V3; //uplink virtual pin for Blynk(led type)
int locktime = V8;//Desired timing setting
long int last_UP_change = millis();
bool runn = 1;
boolean buttonState = 0;
boolean bellState = 0;
boolean bellvalid = 0;

void setup(){
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  Blynk.config(auth, host);

  pinMode(bell, INPUT_PULLUP);    // doorbell button on D4
  pinMode(button, INPUT_PULLUP);  // lock switch on D3
  delay(300);
  pinMode(relay, OUTPUT);         // relay pin on D8
  digitalWrite(relay, LOW);       // relay is OFF on reboot

  SPI.begin();           // Init SPI bus
  mfrc522.PCD_Init();    // Init MFRC522
  timer.setInterval(300L, readRFID);        // Read RFID tags every...
  timer.setInterval(200L, door_status);     // check gate-lock switch every...
  timer.setInterval(300L, doorbell);        // check doorbell button every...
  timer.setInterval(1000L, blinkonoff);      // blynk uplink LED every...
  timer.setInterval(10000L, blynkCheck);    // check server connection every...
}
void blinkonoff(){
    //digitalWrite(relay, LOW); 
    //Blynk.virtualWrite(V5,(WiFi.RSSI()));  
    Blynk.virtualWrite(UP_LED,runn * 255);
    runn = !runn;
    last_UP_change = millis(); 
}

BLYNK_WRITE(V0){
  bellvalid = param.asInt();
  if (bellvalid == 1){
  Blynk.setProperty(V0, "label", "DOORBELL ACTIVE");
  Serial.println("Ring enabled");
  }
  else if(bellvalid == 0){
  Serial.println("Ring disabled");
  Blynk.setProperty(V0, "label", "DOORBELL INACTIVE");
  }
}

BLYNK_WRITE(V8){
  locktime = param.asInt();
}

void blynkCheck() {
  if (WiFi.status() == 3) {
    if (!Blynk.connected()) {
      Serial.println("WiFi OK, trying connection to server...");
      Blynk.connect();   
    }
  }
  if (WiFi.status() == 1) {
    Serial.println("No WiFi connection, going offline.");
  }
}

BLYNK_CONNECTED() {
  // Synchronize time on connection
  rtc.begin();
  setSyncInterval(10 * 60); // Sync interval in seconds (10 minutes)
}

void door_status(){
    buttonState = digitalRead (button);
    if (buttonState < 1){                     // check gate-lock status
    lock++; 
    } 
    
    if (buttonState < 1){                     // check gate-lock status
    Blynk.virtualWrite(V1,"UNLOCKED");
    Blynk.virtualWrite(V4,(lock/4));
    }
    else {
    lock =  0;
    Blynk.virtualWrite(V1,"LOCKED"); 
    } 

    if ((lock/4) > locktime){                     // check gate-lock status
    Blynk.notify("GATE UNLOCKED!!!");
    table.addRow(rowIndex, "Gate unlocked reminder",String(curDateTime()));
    rowIndex++; 
    lock =  0;
    }
}
void doorbell(){
    bellState = digitalRead (bell);
    if ((bellState < 1)&&(bellvalid == 1)){                        // check doorbell button
     Blynk.notify("Enemy at the gates"); 
     table.addRow(rowIndex, "Someone at the gate",String(curDateTime()));
     rowIndex++;
    } 
}

void readRFID(){ 
  digitalWrite(relay, LOW);    // relay is OFF
  if ( ! mfrc522.PICC_IsNewCardPresent()) {     // Look for new tags
    delay(50);
    return;
  }
  if ( ! mfrc522.PICC_ReadCardSerial()) {       // Select one of the tags
    delay(50);
    return;
  }

for (byte i = 0; i < mfrc522.uid.size; i++) {    
  uidDecTemp = mfrc522.uid.uidByte[i];
  uidDec = uidDec * 256 + uidDecTemp;
} 
  Serial.print("Tag ID: ");
  Serial.println(uidDec);
  if ((uidDec == 11111111111&&(buttonState == 1))){
  digitalWrite(relay, HIGH);  // relay is ON
  table.addRow(rowIndex, "Card",String(curDateTime()));
  rowIndex++; 
  delay(300);
 }
 if ((uidDec == 222222222222&&(buttonState == 1))){
  digitalWrite(relay, HIGH);  // relay is ON
  table.addRow(rowIndex, "Mary",String(curDateTime())); 
  rowIndex++; 
  delay(300);
 }
 else{
  digitalWrite(relay, LOW);  // relay is OFF
  Serial.println(uidDec);
}
}


BLYNK_WRITE(V7){
  if (param.asInt() == 1) {
  Blynk.virtualWrite(V6, "clr");
  }
}

BLYNK_WRITE(V2){
  if (param.asInt() == 1&&(buttonState == 1)) {
  digitalWrite(relay, HIGH);  // relay is ON
  Serial.println("Blynk overide");
  table.addRow(rowIndex, "Phone control",String(curDateTime()));
  table.pickRow(rowIndex);
  rowIndex++;
  delay(200);
  digitalWrite(relay, LOW);   
  }
}

void loop(){
  timer.run();
  if (Blynk.connected()) {
  Blynk.run();
  }
}

Here is the server.config

initial.energy=100000
hardware.ssl.port=8441
allow.reading.widget.without.active.app=false
user.message.quota.limit=1000
logs.folder=./Blynk/logs
user.dashboard.max.limit=100
lcd.strings.pool.size=6
server.ssl.key=
webhooks.response.size.limit=72
hardware.mqtt.port=8440
table.rows.pool.size=100
terminal.strings.pool.size=25
admin.email=
admin.rootPath=/admin
user.widget.max.size.limit=50
listen.address=
blocking.processor.thread.pool.limit=6
stats.print.worker.period=60000
enable.db=false
force.port.80.for.csv=false
enable.raw.db.data.store=false
restore.host=blynk-cloud.com
csv.export.data.points.max=43200
restore=false
user.profile.max.size=256
allow.store.ip=true
allowed.users.list=
allowed.administrator.ips=0.0.0.0/0,::/0
net.interface=eth
webhooks.frequency.user.quota.limit=1000
server.host=server.ro
http.port=8080
web.request.max.size=524288
user.devices.limit=100
async.logger.ring.buffer.size=4096
user.tags.limit=500
server.ssl.key.pass=
admin.pass=
hard.socket.idle.timeout=
product.name=Blynk
data.folder=/home/mugur/Blynk
map.strings.pool.size=25
profile.save.worker.period=60000
https.port=9443
log.level=info
server.ssl.cert=
force.port.80.for.redirect=true
contact.email=.......@gmail.com
notifications.queue.limit=2000
notifications.frequency.user.quota.limit=10
region=local

You didn’t clarify the library versions you went from & to… but most likely you swept over the whole port change time frame thing.

I simply add my port in the startup command to be sure the device is aiming for the correct port in the first place.

Blynk.config(auth, host, 8080);

Of course, I use direct IP as all my devices are inside my routers network… you may have other port forwarding issues if you are using a hosted middleman/ddns redirection with your server.ro

Thank you Gunner. I am afraid it is not blynk related, not for the most part anyway. If i disconnect the rfid module everything works perfect. i’ve tried 3 different rfid modules with the same result. Something strange though…if i use an older blynk library like before (0.5.1) it does connect to blynk but never have an working rfid. I think something from mfrc library messed up with the latest blynk library.

i will try with a different rfid module, PN532 this time.