[solved] Superchart only shows live data

Solved
1

I’m looking for some help visualizing my data in the superchart widget. Data shows up in the live tab but it says “Non data yet…” in all others. Data also shows up in the value widgets.

The project:
DHT22 connected to Wemos D1 mini, sending temp and humidity to Blynk server via wifi. Project runs on iPhone and iPad. Everything cool so far.
(A second Wemos listens to remote temp sensor via RF, sends data to value widget; Blynk buttons control remote RF power outlets - works too.)

Only problem is: No historic data in superchart. All I get is “No data yet…”
I assume I am making a simple mistake - but I can’t find it.

Lates Blynk app, latest Blynk library, latest Arduino IDE (Mac OS).

Here is the code - can someone please tell me what I am doing wrong. Thanks!
Love Blynk btw!

Put a 10k resistor between the DHTs VCC and data pin
Commented out lines 155 and 156 in dht.cpp 
    digitalWrite(_pin, HIGH);
    delayMicroseconds(40);  
to fix DHT22 nan readings
*/ 

#include <DHT.h>
#include <DHT_U.h>

#define BLYNK_PRINT Serial            // Comment this out to disable prints and save space
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>


#define DHTPIN 0                      // D3 on Wemos
#define DHTTYPE DHT22

char auth[] = "xxx";
char ssid[] = "yyy";
char pass[] = "zzz";

float Temp_1 = 0;
float Hum_1 = 0;

DHT dht(DHTPIN, DHTTYPE);
BlynkTimer timer;                     //announcig the timer


void setup()
{
  Serial.begin(115200);
  while (!Serial) { }
  Serial.println("Device Started");

  wifi();
  Blynk.begin(auth, ssid, pass);
  dht.begin();
  timer.setInterval(10000L, myTimerEvent);         //set temp/humidity update for every 10 seconds
}


void DHTread()
{
  Temp_1 = dht.readTemperature();         // Read temperature as Celsius (the default)
  Hum_1 = dht.readHumidity();             // Read humidity (the default)

  if (isnan(Hum_1) || isnan(Temp_1))
  {
    Serial.println("Failed to read from DHT sensor");
    return;
  }

  else
  {
    Blynk.virtualWrite(V11, Temp_1, 1);
    Blynk.virtualWrite(V12, Hum_1, 1);

    Serial.print("Temperature: ");
    Serial.print(Temp_1, 1);
    Serial.print(" *C ");
    Serial.print("Humidity: ");
    Serial.print(Hum_1, 1);
    Serial.println(" %\t");
  }
}


void wifi()
{
  WiFi.mode(WIFI_STA);
  WiFi.hostname("DHT-1");
  WiFi.disconnect();                      // Clear any existing connection
  WiFi.begin(ssid, pass);                 // Access WiFi

  Serial.print("Connecting to ");
  Serial.print(ssid);
  Serial.print(" ...");

  while (WiFi.status() != WL_CONNECTED)
  {
    delay(1000);
    Serial.print(".");
  }

  Serial.println('\n');
  Serial.println("WiFi connection established");
  Serial.print("Device's IP address is ");
  Serial.println(WiFi.localIP());           // Show device's IP address
}


void myTimerEvent()
{
  DHTread();
}


void loop()
{
  Blynk.run();
  timer.run();
}
2

Unlike the Serial.print() function, the Blynk.virtualWrite() function does not take any formatting parameters. You need to change

Blynk.virtualWrite(V11, Temp_1, 1);
Blynk.virtualWrite(V12, Hum_1, 1);

to

Blynk.virtualWrite(V11, Temp_1);
Blynk.virtualWrite(V12, Hum_1);
3

Brilliant! Thank you!